1

Konu: Outlook İle Mail

Outlook ile mail göndermek istiyorum.  Kodlarımı oluşturdum. Outlook açıkken çalışıyor. Ancak Outlook kapalı iken mail gönderemiyorum. Outlooku kapatınca Mail gitmiyor. Müşteriye de önce Outlooku aç demek pek uygun değil. Ne yapabilirim?

Visual Fox Pro
oMail=CreateObject("outlook.application")

oItem = oMail.CreateItem(0)
oItem.Subject = Alltrim(thisform.text1.Value)
 
oItem.To="info@denbil.com"
oItem.Cc = Alltrim(thisform.edit1.Value)
oItem.Body= Alltrim(thisform.edit2.Value)
*oitem.Attachments.Add("c:\deneme.xls")
 
Try 
   oItem.Send
   Wait "Mesaj Gönderimi Başarılı..." window timeout 1
Catch
   Wait "Mesaj Gönderilemedi..." window timeout 1
EndTry
 
oMail=.Null.

2

Re: Outlook İle Mail

gmail yada hotmail servislerini kullanabilirsiniz.

Visual Fox Pro
=SendMailViaLive("soykanozcelik@hotmail.com","XXXXXXXX","blabla@gmail.com","live mail test","deneme mail live.com dan  ")

=SendMailViaGmail("soykanozcelik@gmail.com","XXXXXXXX","blabla@hotmail.com","Gmail mail test","deneme mail gmail.com dan")
 
*------------------------------------------------------------------------------
Function SendMailViaGmail(tcUserName,tcPassword,tcTo,tcSubject,tcBody)
loMail = Newobject("Cdo2000")
With loMail
    .cServer = "smtp.gmail.com"
    .nServerPort = 465 
    .lUseSSL = .T.
 
    .nAuthenticate = 1     && cdoBasic
    .cUserName = m.tcUserName   && "<a href="mailto:yourGmailAccount@gmail.com">yourGmailAccount@gmail.com</a>"
    .cPassword = m.tcPassword  &&"yourGmailPassword"
 
* If From address doesn't match any of the registered identities,
*    Gmail will replace it with your default Gmail address
    .cFrom = .cUserName && "<a href="mailto:yourGmailAccount@gmail.com">yourGmailAccount@gmail.com</a>"
 
    .cTo = m.tcTo && "<a href="mailto:somebody@otherdomain.com">somebody@otherdomain.com</a>, <a href="mailto:somebodyelse@otherdomain.com">somebodyelse@otherdomain.com</a>"
 
    .cSubject = m.tcSubject &&"CDO 2000 email through Gmail SMTP server"
 
* Uncomment next lines to send HTML body
*.cHtmlBody = "<html><body><b>This is an HTML body<br>" + ;
*        "It'll be displayed by most email clients</b></body></html>"
 
.cTextBody = m.tcBody
    *-.cTextBody = "This is a text body." + Chr(13) + Chr(10) + ;
        "It'll be displayed if HTML body is not present or by text only email clients"
 
* Attachments are optional
* .cAttachment = "myreport.pdf, myspreadsheet.xls"
Endwith
 
If loMail.Send() > 0
    For i=1 To loMail.GetErrorCount()
        *-? i, loMail.Geterror(i)
        Messagebox(loMail.Geterror(i))
    Endfor
* Clear errors
    loMail.ClearErrors()
Else
    *-? "Email sent."
    Messagebox("Mail Başarı ile Gönderildi...",64,"Gmail Mail Gönderim",1)
Endif
Endfunc
*------------------------------------------------------------------------------
Function SendMailViaLive(tcUserName,tcPassword,tcTo,tcSubject,tcBody)
 
loMail = Newobject("Cdo2000")
With loMail
    .cServer = "smtp.live.com"
    .nServerPort = 25
    .lUseSSL = .T.
 
    .nAuthenticate = 1     && cdoBasic
    .cUserName =  m.tcUserName   && "<a href="mailto:yourAccount@live.com">yourAccount@live.com</a>"
    .cPassword =  m.tcPassword  &&"yourPassword"
 
*.cFrom = "<a href="mailto:yourlAccount@live.com">yourlAccount@live.com</a>"
 
    .cFrom = .cUserName
 
    .cTo = m.tcTo && "<a href="mailto:somebody@otherdomain.com">somebody@otherdomain.com</a>, <a href="mailto:somebodyelse@otherdomain.com">somebodyelse@otherdomain.com</a>"
 
    .cSubject = m.tcSubject && "CDO 2000 email through MSN SMTP server"
 
* Uncomment next lines to send HTML body
*.cHtmlBody = "<html><body><b>This is an HTML body<br>" + ;
*        "It'll be displayed by most email clients</b></body></html>"
 
.cTextBody = m.tcBody
    *-.cTextBody = "This is a text body." + Chr(13) + Chr(10) + ;
        "It'll be displayed if HTML body is not present or by text only email clients"
 
* Attachments are optional
* .cAttachment = "myreport.pdf, myspreadsheet.xls"
Endwith
 
If loMail.Send() > 0
    For i=1 To loMail.GetErrorCount()
*-? i, loMail.Geterror(i)
        Messagebox(loMail.Geterror(i))
    Endfor
* Clear errors
    loMail.ClearErrors()
Else
*-? "Email sent."
    Messagebox("Mail Başarı ile Gönderildi...",64,"Live Mail Gönderim",1)
Endif
 
Endfunc
 
*--------------------------------------------------------
#Define cdoSendPassword "http://schemas.microsoft.com/cdo/configuration/sendpassword"
#Define cdoSendUserName "http://schemas.microsoft.com/cdo/configuration/sendusername"
#Define cdoSendUsingMethod "http://schemas.microsoft.com/cdo/configuration/sendusing"
#Define cdoSMTPAuthenticate "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
#Define cdoSMTPConnectionTimeout "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
#Define cdoSMTPServer "http://schemas.microsoft.com/cdo/configuration/smtpserver"
#Define cdoSMTPServerPort "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
#Define cdoSMTPUseSSL "http://schemas.microsoft.com/cdo/configuration/smtpusessl"
#Define cdoURLGetLatestVersion "http://schemas.microsoft.com/cdo/configuration/urlgetlatestversion"
#Define cdoAnonymous 0    && Perform no authentication (anonymous)
#Define cdoBasic 1    && Use the basic (clear text) authentication mechanism.
#Define cdoSendUsingPort 2    && Send the message using the SMTP protocol over the network.
#Define cdoXMailer "urn:schemas:mailheader:x-mailer"
 
Define Class cdo2000 As Custom
 
    Protected aErrors[1], nErrorCount, oMsg, oCfg, cXMailer
 
    nErrorCount = 0
 
* Message attributes
    oMsg = Null
    cFrom = ""
    cReplyTo = ""
    cTo = ""
    cCC = ""
    cBCC = ""
    cAttachment = ""
 
    cSubject = ""
    cHtmlBody = ""
    cTextBody = ""
    cHtmlBodyUrl = ""
 
    cCharset = ""
 
* Configuration object fields values
    oCfg = Null
    cServer = ""
    nServerPort = 25
* Use SSL connection
    lUseSSL = .F.
    nConnectionTimeout = 30            && Default 30 sec's
    nAuthenticate = cdoAnonymous
    cUserName = ""
    cPassword = ""
* Do not use cache for cHtmlBodyUrl
    lURLGetLatestVersion = .T.
 
* Optional. Creates your own X-MAILER field in the header
    cXMailer = "VFP CDO 2000(CDOSYS) mailer Ver 1.1 2009"
 
    Protected Procedure Init
        This.aErrors = Null
        Endproc
 
* Send message
    Procedure Send
 
    With This
        .ClearErrors()
        .oCfg = Createobject("CDO.Configuration")
        .oMsg = Createobject("CDO.Message")
        .oMsg.Configuration = This.oCfg
    Endwith
 
* Fill message attributes
    Local lnind, laList[1], loHeader, laDummy[1]
 
    If This.SetConfiguration() > 0
        Return This.GetErrorCount()
    Endif
 
    If Empty(This.cFrom)
        This.AddError("HATA : Kimden kısmı boş!")
    Endif
    If Empty(This.cSubject)
        This.AddError("HATA : Konu kısmı boş!")
    Endif
 
    If Empty(This.cTo) And Empty(This.cCC) And Empty(cBCC)
        This.AddError("HATA : Kime,Karbon Kopya ve Gizli Karbon Kopya alanları boş!")
    Endif
 
    If This.GetErrorCount() > 0
        Return This.GetErrorCount()
    Endif
 
    This.SetHeader()
 
    With This.oMsg
 
        .From     = This.cFrom
        .ReplyTo  = This.cReplyTo
 
        .To       = This.cTo
        .CC       = This.cCC
        .BCC      = This.cBCC
        .Subject  = This.cSubject
 
* Create HTML body from external HTML (file, URL)
        If Not Empty(This.cHtmlBodyUrl)
            .CreateMHTMLBody(This.cHtmlBodyUrl)
        Endif
 
* Send HTML body. Creates TextBody as well
        If Not Empty(This.cHtmlBody)
            .HtmlBody = This.cHtmlBody
        Endif
 
* Send Text body. Could be different from HtmlBody, if any
        If Not Empty(This.cTextBody)
            .TextBody = This.cTextBody
        Endif
 
        If Not Empty(.HtmlBody)
            .HtmlBodyPart.Charset = This.cCharset
        Endif
 
        If Not Empty(.TextBody)
            .TextBodyPart.Charset = This.cCharset
        Endif
 
* Process attachments
        If Not Empty(This.cAttachment)
* Accepts comma or semicolon
* VFP 7.0 and later
*FOR lnind=1 TO ALINES(laList, This.cAttachment, [,], [;])
* VFP 6.0 and later compatible
            For lnind=1 To Alines(laList, Chrtran(This.cAttachment, [,;], Chr(13) + Chr(13)))
                lcAttachment = Alltrim(laList[lnind])
* Ignore empty values
                If Empty(laList[lnind])
                    Loop
                Endif
 
* Make sure that attachment exists
                If Adir(laDummy, lcAttachment) = 0
                    This.AddError("HATA: Eklenti Bulunamadı - " + lcAttachment)
                Else
* The full path is required.
                    If     Upper(lcAttachment) <> Upper(Fullpath(lcAttachment))
                        lcAttachment = Fullpath(lcAttachment)
                    Endif
                    .AddAttachment(lcAttachment)
                Endif
            Endfor
        Endif
 
        If Not Empty(This.cCharset)
            .BodyPart.Charset = This.cCharset
        Endif
 
    Endwith
 
 
    If This.GetErrorCount() > 0
        Return This.GetErrorCount()
    Endif
 
    This.oMsg.Send()
 
    Return This.GetErrorCount()
 
    Endproc
 
* Clear errors collection
    Procedure ClearErrors()
    This.nErrorCount = 0
    Dimension This.aErrors[1]
    This.aErrors[1] = Null
    Return This.nErrorCount
    Endproc
 
* Return # of errors in the error collection
    Procedure GetErrorCount
    Return This.nErrorCount
    Endproc
 
* Return error by index
    Procedure Geterror
    Lparameters tnErrorno
    If    tnErrorno <= This.GetErrorCount()
        Return This.aErrors[tnErrorno]
    Else
        Return Null
    Endif
    Endproc
 
* Populate configuration object
    Protected Procedure SetConfiguration
 
* Validate supplied configuration values
        If Empty(This.cServer)
            This.AddError("HATA: SMTP Sunucu belirtilmedi!")
        Endif
        If Not Inlist(This.nAuthenticate, cdoAnonymous, cdoBasic)
            This.AddError("HATA: Geçersiz Doğrulama Protokolu! ")
        Endif
        If This.nAuthenticate = cdoBasic ;
                AND (Empty(This.cUserName) Or Empty(This.cPassword))
            This.AddError("HATA: Kullanıcı Adı/Şifre Gerekli!")
        Endif
 
        If     This.GetErrorCount() > 0
            Return This.GetErrorCount()
        Endif
 
        With This.oCfg.Fields
 
* Send using SMTP server
            .Item(cdoSendUsingMethod)           = cdoSendUsingPort
            .Item(cdoSMTPServer)                = This.cServer
            .Item(cdoSMTPServerPort)            = This.nServerPort
            .Item(cdoSMTPConnectionTimeout)         = This.nConnectionTimeout
 
            .Item(cdoSMTPAuthenticate)          = This.nAuthenticate
            If This.nAuthenticate = cdoBasic
                .Item(cdoSendUserName)              = This.cUserName
                .Item(cdoSendPassword)              = This.cPassword
            Endif
            .Item(cdoURLGetLatestVersion)           = This.lURLGetLatestVersion
            .Item(cdoSMTPUseSSL)                 = This.lUseSSL
 
            .Update()
        Endwith
 
        Return This.GetErrorCount()
 
        Endproc
 
*----------------------------------------------------
* Add message to the error collection
    Protected Procedure AddError
        Lparameters tcErrorMsg
        This.nErrorCount = This.nErrorCount + 1
        Dimension This.aErrors[This.nErrorCount]
        This.aErrors[This.nErrorCount] = tcErrorMsg
        Return This.nErrorCount
        Endproc
 
*----------------------------------------------------
* Format an error message and add to the error collection
    Protected Procedure AddOneError
        Lparameters tcPrefix, tnError, tcMethod, tnLine
        Local lcErrorMsg, laList[1]
        If Inlist(tnError, 1427,1429)
            Aerror(laList)
            lcErrorMsg = Transform(laList[7], "@0") + ;
                "  " + laList[4]  + "  " + laList[3]
        Else
            lcErrorMsg = Message()
        Endif
        This.AddError(tcPrefix + ":" + Transform(tnError) + " # " + ;
            tcMethod + " # " + Transform(tnLine) + " # " + lcErrorMsg)
        Return This.nErrorCount
        Endproc
 
*----------------------------------------------------
* Simple Error handler. Adds VFP error to the objects error collection
    Protected Procedure Error
        Lparameters tnError, tcMethod, tnLine
*!*            This.AddError("VFP Error: " + TRANSFORM(tnError) + " # " + ;
*!*                tcMethod + " # " + TRANSFORM(tnLine) + " # " + MESSAGE())
        This.AddOneError("ERROR: ", tnError, tcMethod, tnLine )
        Return This.nErrorCount
        Endproc
 
*-------------------------------------------------------
* Set mail header fields, if necessary. For now sets X-MAILER, if specified
    Protected Procedure SetHeader
        Local loHeader
        If Not Empty(This.cXMailer)
            loHeader = This.oMsg.Fields
            With loHeader
                .Item(cdoXMailer) =  This.cXMailer
                .Update()
            Endwith
        Endif
        Endproc
 
Enddefine
http://www.soykansoft.com/images/twitter.jpghttp://www.soykansoft.com/images/wp.jpg

3

Re: Outlook İle Mail

^  (Soykan'ın koduna şapka çıkarma işareti)
Outlook veya live MSun keyfi-kader değişiklikleri ile koda karşı davranışı değişebilir diye varsaydığımdan, gmail diğerlerinden çok yaşayacak diye düşünüyorum.

VFP9 SP2

4

Re: Outlook İle Mail

Çok faydalı bir kod olacak benim için. Sağol Soykan.

5

Re: Outlook İle Mail

Soykan, merhabalar

Biliyorum, smentes isimli üyenin sorularına cevap vermek senin görevin. Görev olduğu için smentes tabii sana teşekkür etmek zorunda değil.
Ben onun yerinde olsam "ileri dönük yatırım" başlık altında mırın kırın ederek teşekkür gibi birkaç kelime sarf ederdim; olurya bir gün bu görev bir son bulur.
Çünkü geçmişde bende smentes üyemizin sorunlarına çözüm bulmak için çırpınıyordum. Ama baktım ki ne bir geri dönüş, ne bir teşekkür var ...
Herkes kendisi bilir.

Bendende bu kodlar için sana bol bol teşekkürler.

Bir projenin bitmesi için 3 seçenek vardır: hızlı, ucuz, iyi. Bu seçeneklerden iki tanesini seçiniz.

6

Re: Outlook İle Mail

Selamlar, smentes' in foruma olan gönderilerini incelerseniz, 2 mesajından biri teşekkür mesajı. Yani O bu forumda değerli dediğiniz soru soranlardan.  Hatta sadece soru sormuş ve cevap almış.  Bu kez teşekkür etmeyi muhtemelen unutmuştur yada bu mesajı yazacak zamanı olmamıştır.

Aslında bu kadar az soru sorulması buradaki herkesin hayatını değiştiren FoxPro nun tarihte yerini almakta olduğunu gösteriyor. Bilmiyorum kaçınız yeni bir projeye VFP ile başlıyorsunuz. Belkide bir çoğumuz VFP' yi terketti. Ben en son 2009  da bir VFP projesi yaptım.

Sonrası .NET...

7

Re: Outlook İle Mail

Konu email gönderme den açıldıgı için bir sorum olacak arkadaşlar

g-mail ile e-mail gönderiyoruz ama giden e-mailler karşıda takma isim veya kullancı adı ile çıkarmamız mümkünmü

zira bize gelen e-maillerde çogu mail takma ad veya firma adı ile geliyor

Bilgi Paylaşıldıkça Artar...!

8

Re: Outlook İle Mail

Çok değerli üyeler,

Enbüyük eksikliğimiz peşin fikirlilik ve karşı tarafın savunmasını almadan karar vermektir. Belki de bu çok fazla ve gereksiz özgüvenden kaynaklanıyor.  Cuma günü sorumu sordum.  Soykan beyin cevap verdiği saatlerde maalesef ben internetten yoksundum. Özel işlerim için il dışındaydım. Şu anda ancak internete girebildim ve cevapları okuma fırsatım oldu. Ben emeğin ne olduğunu bilin birisiyim. Bir harfin 40 yıl hatırı olduğunu özünde hissedenlerdenim. Ben bir emekli öğretmenim. Öğretmenin, öğrenmenin değerini bilen ve yıllarca uygulayan birisiyim. Bu forma üye olduğum 01.09.2006 dan beri ilk defa kodlar dışında birkaç cümle yazıyorum. Bunun için de özür diliyorum. Sayın Mehmet K' ya bu uyarısından dolayı teşekkür ediyorum. Sayın Aligöçmen'e de düşüncelerime tercüman olduğu için.

1-Sayın Soykan Beyin yazmış olduğu kodları daha önce forumda gördüm. Bir soru sormadan önce forumda arama yaparım. Soruma cevap bulamazsan siz değerli üyelerin bilgilerine müracaat ederim. Ancak müşterim outlook kullandığı için özellikle istedi. Outlook olması gerekiyordu.
2-2006 dan beri üye olduğum için işin ilk abc sinde iken, Soykan bey ve diğer üstadlar, bizlere yardımcı olmak için gerçekten sabır gösterdiler. Birkez daha onlara teşekkür ediyorum.
3-Yorumlara zamanında cevap veremedim Yukarıda bahsettiğim gibi il dışında ve internetten uzakta idim.
4-Olumlu veya olumsuz cevap veren, hatta okuyan tüm üyelere teşekkür ediyorum.
5-Hala sorumun cevabı ile ilgili bir bilgiye ulaşamadım.

9

Re: Outlook İle Mail

Galiba müşterin giden maillerin outlook veritabanında tutulmasını istiyor.
Senin kodları aşağıdaki gibi denersen outlook kapalı olsa da gönderir.

Visual Fox Pro
oMail=CreateObject("outlook.application")

oNs=oMail.GetNamespace("MAPI")
oNs.Logon
oItem = oMail.CreateItem(0)
oItem.Subject = Alltrim(thisform.text1.Value)
 
oItem.To="info@denbil.com"
oItem.Cc = Alltrim(thisform.edit1.Value)
oItem.Body= Alltrim(thisform.edit2.Value)
*oitem.Attachments.Add("c:\deneme.xls")
Try 
   oItem.Send
   Wait "Mesaj Gönderimi Başarılı..." window timeout 1
Catch
   Wait "Mesaj Gönderilemedi..." window timeout 1
EndTry
oMail=.Null.

10

Re: Outlook İle Mail

en basit kullanimi Outlook kapali olsada acar ve izin ister ardindan gonderir.

Visual Fox Pro
*- with permission

 
o=createobject("outlook.application")
oitem=o.createitem(0)
oitem.subject="Email From VFP9"
 
oitem.to="soykanozcelik@hotmail.com"
** To send copy to addresses..
oItem.cc = "soykanozcelik@hotmail.com;soykanozcelik@icloud.com"
 
oitem.body="This mail was sent from vfp using Outlook2013"
 
** To attach a file
*-oitem.Attachments.Add("MyFullPath+MyFile+Ext")
** to attach one more file.. and you can repeat this.
*- oitem.Attachments.Add("MyFullPath+MyFile+Ext")
 
** to send it
oitem.send
 
** to clear up
o=.null.
http://www.soykansoft.com/images/twitter.jpghttp://www.soykansoft.com/images/wp.jpg

11

Re: Outlook İle Mail

buda baska bir ornek

Visual Fox Pro
#DEFINE olImportanceLow 0

#DEFINE olImportanceNormal 1
#DEFINE olImportanceHigh 2
 
DIMENSION aryAttach(2)
*-aryAttach(1) = "C:\attachment1.txt" && change to an actual file that exists on your computer
*-aryAttach(2) = "C:\attachment2.zip" && change to an actual file that exists on your computer
 
LOCAL lcTo, lcSubject, lcBody, lcCC, lcBCC, llHTMLFormat, llOpenEmail, lcErrReturn
 
lcTo = "soykanozcelik@hotmail.com"
lcSubject = "email from VFP via Outlook"
*!* Sending the body in HTML format
llHTMLFormat = .T.
lcBody = "<a href='http://www.fox4um.com'></a>"
lcCC = "soykanozcelik@gmail.com"
lcBCC = "soykanozcelik@icloud.com"
 
*!* to automatically send email set llOpenEmail to .F.
llOpenEmail = .f. && Whether email is opened in Outlook or not
 
*-SendViaOutlook(@lcErrReturn, lcTo, lcSubject, lcBody, @aryAttach, lcCC, lcBCC, llHTMLFormat, olImportanceHigh, llOpenEmail)
SendViaOutlook(@lcErrReturn, lcTo, lcSubject, lcBody,  lcCC, lcBCC, llHTMLFormat, olImportanceHigh, llOpenEmail)
 
IF EMPTY(lcErrReturn)
MESSAGEBOX("'" + lcSubject + "'" + IIF(llOpenEmail, " opened ", " sent ") + "successfullly.", 64, "Send email via Outlook")
ELSE
MESSAGEBOX("'" + lcSubject + "' failed to be sent.  Reason:" + CHR(13) + lcErrReturn, 64, "Send email via Outlook")
ENDIF
 
*******************************************
*-PROCEDURE SendViaOutlook(tcReturn, tcTo, tcSubject, tcBody, taFiles, tcCC, tcBCC, tlHTMLFormat, tnImportance, tlOpenEmail)
PROCEDURE SendViaOutlook(tcReturn, tcTo, tcSubject, tcBody, tcCC, tcBCC, tlHTMLFormat, tnImportance, tlOpenEmail)
*******************************************
LOCAL loOutlook, loItem, lnCountAttachments, loMapi
TRY
  loOutlook = CREATEOBJECT("outlook.application")
  loMapi = loOutLook.GetNameSpace("MAPI")
  loMapi.Logon()
  loItem = loOutlook.CreateItem(0)
  WITH loItem
   .Subject = tcSubject
   .TO = tcTo
   IF tlHTMLFormat
    .HTMLBody = tcBody
   ELSE
    .Body = tcBody
   ENDIF
   IF TYPE("tcCC") = "C"
    .CC = tcCC
   ENDIF
   IF TYPE("tcBCC") = "C"
    .BCC = tcBCC
   ENDIF
   IF TYPE("tnImportance") != "N"
    tnImportance = 1 && normal importance
   ENDIF
   .Importance = tnImportance
   IF TYPE("tafiles",1) = "A"
    FOR lnCountAttachments = 1 TO ALEN(taFiles)
     .Attachments.ADD(taFiles(lnCountAttachments))
    ENDFOR
   ENDIF
   IF tlOpenEmail
    .DISPLAY()
   ELSE
    .SEND()
   ENDIF
  ENDWITH
CATCH TO loError
  tcReturn = [Error: ] + STR(loError.ERRORNO) + CHR(13) + ;
   [LineNo: ] + STR(loError.LINENO) + CHR(13) + ;
   [Message: ] + loError.MESSAGE + CHR(13) + ;
   [Procedure: ] + loError.PROCEDURE + CHR(13) + ;
   [Details: ] + loError.DETAILS + CHR(13) + ;
   [StackLevel: ] + STR(loError.STACKLEVEL) + CHR(13) + ;
   [LineContents: ] + loError.LINECONTENTS
FINALLY
  RELEASE oOutlook, oItem
  STORE .NULL. TO oOutlook, oItem
ENDTRY
ENDPROC
http://www.soykansoft.com/images/twitter.jpghttp://www.soykansoft.com/images/wp.jpg

12

Re: Outlook İle Mail

"en basit kullanimi Outlook kapali olsada acar ve izin ister ardindan gonderir."

Şu izin isteme iş çok kötü. Her mail için 1 kaç saniye kaybettiriyor.  Ve hep "izin ver " e bastırıyordu galiba..


En iyisi direk mail yollamak.

13

Re: Outlook İle Mail

Evet bu konudada en basarili Gmail

http://www.soykansoft.com/images/twitter.jpghttp://www.soykansoft.com/images/wp.jpg

14

Re: Outlook İle Mail

Sayın msayin,
Yazdığınız bölümleri ilave ettim. Profil seç bölümü geliyor. Ancak önemli değil. Bu yeterli. Profil seç bölümünden seçeneklerden varsayılan profil yap işaretledim. Artık izin bölümü de gelmiyor. Teşekkür ederim.