VFP icinden MySQL kullanma

**tbasoz** · 13.10.2006 13:47:28

tbasoz
Üye
Offline

Kayıt Tarihi: 13.10.2006
İleti: 11

Konu: VFP icinden MySQL kullanma

Eğer bu konuda yardım isteyen olursa seve seve yardım ederim. VFP den MySQL kullanımı hakkında sanırım epey bir deneyimimiz var. Insert, update, delete, ... isteyen olursa örnek çalışan kodlar gönderebilirim.

Tekin Başöz
Yapay Zeka Ltd.

**soykanozcelik** · 13.10.2006 14:50:23

soykanozcelik
-
Offline

Yer: Tekirdağ
Kayıt Tarihi: 25.08.2006
İleti: 1,189

Re: VFP icinden MySQL kullanma

biz Ahmetle cursoradapter ile bir web sitesindeki haber datalarina ulasip haber ekleme,silme,degistirme yapabildik sadece charset te takıldık ona bir seyler yapamadık detayları bu mesajı okuyunca Ahmet devamını yazar onu konu uzerinde çözüm üretmeye çalışırız.

http://www.soykansoft.com/images/twitter.jpg

http://www.soykansoft.com/images/blogger.jpg

**mrduyar** · 13.10.2006 16:37:40

mrduyar
Üye
Offline

Yer: Antalya
Kayıt Tarihi: 09.10.2006
İleti: 514

Re: VFP icinden MySQL kullanma

mysql ile ilgili döküman gönderebilirseniz memnun olurum.
emal: [email protected]

Bilmediğin Neyse Yanıldığındır.

**ahmetozkaya** · 15.10.2006 01:31:26

ahmetozkaya
<%
Offline

Kayıt Tarihi: 23.08.2006
İleti: 62

Re: VFP icinden MySQL kullanma

CA ile bağlandığımız mysql'in charset problemini aşağıdaki şekilde çözmüştüm.

Visual Fox Pro

This.FetchMemoDataSource = sqlstringconnect([DRIVER={MySQL ODBC 3.51 Driver};SERVER=localhost;DATABASE=db_name;US] + ;

    [ER=mysql_user;PASSWORD=mysql_pass;OPTION=35;])

    ? SQLEXEC(This.DataSource , [SET NAMES 'latin5'])

Aslında insert, delete, update lerde problemimiz yok. Benim kafama takılan, mysql den çektiğimiz html verisini editlemeyi kolaylaştıracak editor. Şimdilik bu problemi activeX'in webbrowser objesinin edit modunu kullanarak basit kontrolleri sağladık. Başlıkla ilgili değil ama yinede sorayım, html veriyi görsel olarak editleyebileceğim farklı bir class yada kütüphane varmıdır?

Birde VFP+MySQL ile ilgili dökümanlar bölümüne bir döküman hazırlamak istiyorum, genel vfp mysql iletişimi ile ilgili, uygun olursa sizin katkılarınız ile.

**Ozgur** · 16.10.2006 14:28:58

Ozgur
Üye
Offline

Kayıt Tarihi: 16.10.2006
İleti: 1

Re: VFP icinden MySQL kullanma

slm
c# mobile edition'da Foxpro dbf dosyalırını kullanabilirmiiym...

**tbasoz** · 21.04.2007 09:06:39

tbasoz
Üye
Offline

Kayıt Tarihi: 13.10.2006
İleti: 11

Re: VFP icinden MySQL kullanma

Birçok arkadaştan özelime bu konu ile ilgili istek gelince örnek kodları buraya yazıyım dedim. Aşağıdaki örnekte Ad, Soyad, Yas ve Maas bilgileri MySQL de tanımlı olduğunu varsaydığımız basit bir uygulama göreceksiniz. Bu uygulama da MySQL e connect, data okuma, data yazma, data silme ve güncellem ile ilgili işlemleri görebilirsiniz (Insert, Update, Delete). Aşağıdaki kodları istediğiniz gibi alıp kendi uygulamalarınızda kullnabilirsiniz. Umarım herkes için faydalı olur.

Visual Fox Pro

**************************************************************************

**  VFP de MySQL kullanimina ornek                                      **

**  (c)1993-2007 Yapay Zeka Ltd.                                        **

**  Istediginiz gibi istediginiz uygulamalarinizda kullanabilirsiniz.   **

**  Son Guncelleme : 24/02/2007                                         **

**************************************************************************

**  Bu ornekte, mySQL de tanimlanmis 'Deneme' isimli tabloda ad,soyad,  **

**  yas,maas bilgileri bulunmaktadir. Siz dilediginiz gibi degisiklik   **

**  yapabilirsiniz.                                                     **

**************************************************************************

Clear All

Public oForm

oForm = CreateObject('MyForm')

oForm.Show()

Return 

 

******************************************************************

Define Class MyForm as Form

******************************************************************

    Height = 400

    Width = 650

    Caption = 'MySQL Sample'

    Name = 'MyForm'

    AutoCenter = .t.

    tnHandle = 0

    tcTable = 'Deneme'

    

 

    Add Object lblServer as Label With ;

        Top = 375, ;

        Left = 4, ;

        Caption = 'Server'

        

    Add Object txtServer as TextBox With ;

        Top = 372, ;

        Left = 52, ;

        Value = 'localhost', ;

        SelectOnEntry = .t.

 

    Add Object lblDatabase as Label With ;

        Top = 375, ;

        Left = 160, ;

        Caption = 'Database'

 

    Add Object txtDatabase as TextBox With ;

        Top = 372, ;

        Left = 223

 

    Add Object lblUserName as Label With ;

        Top = 375, ;

        Left = 330, ;

        Caption = 'Kullanıcı Adı'

 

    Add Object txtUserName as TextBox With ;

        Top = 372, ;

        Left = 403

 

    Add Object lblPassword as Label With ;

        Top = 375, ;

        Left = 511, ;

        Caption = 'Şifre'

 

    Add Object txtPassword as TextBox With ;

        Top = 372, ;

        Left = 545, ;

        PasswordChar = '*'

 

    Add Object lblAd as Label With ;

        Top = 15, ;

        Left = 9, ;

        Caption = 'Adı'

 

    Add Object txtAd as myTextBox With ;

        Top = 12, ;

        Left = 30

 

    Add Object lblSoyad as Label With ;

        Top = 15, ;

        Left = 135, ;

        Caption = 'Soyadı'

 

    Add Object txtSoyad as myTextBox With ;

        Top = 12, ;

        Left = 177

 

    Add Object lblYas as Label With ;

        Top = 15, ;

        Left = 284, ;

        Caption = 'Yaşı'

 

    Add Object txtYas as myTextBox With ;

        Top = 12, ;

        Left = 316, ;

        Width = 69

        

    Add Object lblMaas as Label With ;

        Top = 15, ;

        Left = 392, ;

        Caption = 'Maaşı'

 

    Add Object txtMaas as myTextBox With ;

        Top = 12, ;

        Left = 429, ;

        Value = 0

 

    Add Object grdListe as myGrid

 

    Add Object shpBorder1 as Shape with ;

        Top = 363, ;

        Left = 0, ;

        Height = 3, ;

        Width = 650, ;

        SpecialEffect = 0

 

    Add Object shpBorder2 as Shape with ;

        Top = 0, ;

        Left = 537, ;

        Height = 364, ;

        Width = 3, ;

        SpecialEffect = 0

 

    Add Object cmdConnect as CommandButton With ;

        Top = 12, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = "Connect" 

 

    Add Object cmdDisconnect as CommandButton With ;

        Top = 12, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = "Disconnect", ;

        Visible = .f.   

 

    Add Object cmdListe as CommandButton With ;

        Top = 46, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Listele', ;

        Enabled = .f.

    

    Add Object cmdNew as CommandButton With ;

        Top = 80, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Yeni Kayıt', ;

        Enabled = .f.

 

    Add Object cmdSave as CommandButton With ;

        Top = 80, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Sakla', ;

        Visible = .f.

 

    Add Object cmdEdit as CommandButton With ;

        Top = 114, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Düzelt', ;

        Enabled = .f.

 

    Add Object cmdUpdate as CommandButton With ;

        Top = 114, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Sakla', ;

        Visible = .f.

 

    Add Object cmdDelete as CommandButton With ;

        Top = 148, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Sil', ;

        Enabled = .f.

 

    Add Object cmdClose as CommandButton With ;

        Top = 182, ;

        Left = 552, ;

        Height = 27, ;

        Width = 84, ;

        Caption = 'Kapat'

 

    Add Object cmdSaveServerInfo as CommandButton With ;

        Top = 300, ;

        Left = 552, ;

        Height = 55, ;

        Width = 84, ;

        Caption = "Server Bilgilerini Kaydet", ;

        WordWrap = .t.

 

    Procedure Init

        If File('ServerInfo.ini')

            m.lcServerInfo = FileToStr('ServerInfo.ini')

            With thisform

                .txtServer.Value   = Mline(lcServerInfo, 1)

                .txtDatabase.Value = Mline(lcServerInfo, 2)

                .txtUserName.Value = Mline(lcServerInfo, 3)

                .txtPassword.Value = Mline(lcServerInfo, 4)

            EndWith     

        EndIf 

    EndProc 

 

    Procedure cmdConnect.Click

        mySQLConnect()

    EndProc 

 

    Procedure cmdDisconnect.Click

        mySQLDisconnect()

    EndProc 

 

    Procedure cmdListe.Click 

        mySQLList()

    EndProc 

    

    Procedure cmdNew.Click 

        mySQLNew()

    EndProc 

 

    Procedure cmdSave.Click 

        mySQLSave()

    EndProc 

 

    Procedure cmdEdit.Click 

        mySQLEdit()

    EndProc 

 

    Procedure cmdUpdate.Click 

        mySQLUpdate()

    EndProc 

 

    Procedure cmdDelete.Click 

        mySQLDelete()

    EndProc 

 

    Procedure cmdClose.Click 

        thisform.Release 

    EndProc 

 

    Procedure cmdSaveServerInfo.Click

        m.lcServerInfo = Alltrim(thisform.txtServer.Value) + Chr(13) +;

            Alltrim(thisform.txtDatabase.Value) + Chr(13) +;

            Alltrim(thisform.txtUserName.Value) + Chr(13) +;

            Alltrim(thisform.txtPassword.Value)

        StrToFile(lcServerInfo,'ServerInfo.ini',0)

    EndProc 

EndDefine 

 

******************************************************************

Define Class myGrid as Grid 

******************************************************************

    Top = 45

    Left = 20

    Height = 310

    Width = 500

    ColumnCount = 4

    DeleteMark = .f.

    RecordMark = .f.

    ScrollBars = 2

    GridLineColor = Rgb(192,192,192)

    

    Procedure Init

        With this

            .Column1.Header1.Caption = 'Adı'

            .Column1.Width = 150        

            .Column2.Header1.Caption = 'Soyadı'

            .Column2.Width = 150        

            .Column3.Header1.Caption = 'Yaşı'

            .Column4.Header1.Caption = 'Maaşı'

            .Column4.Width = 100        

        EndWith 

    EndProc 

    

    Procedure AfterRowColChange

        Lparameters nColIndex

        DoDefault(nColIndex)

        With oForm

            .txtAd.Value = Ad

            .txtSoyad.Value = Soyad

            .txtYas.Value = Yas

            .txtMaas.Value = Maas

        EndWith 

    EndProc 

EndDefine 

 

******************************************************************

Define Class myTextBox as TextBox

******************************************************************

    Enabled = .f.

    DisabledForeColor = Rgb(0,0,0)

    SelectOnEntry = .t.

EndDefine 

 

******************************************************************

Procedure mySQLConnect

******************************************************************

    With oForm

        m.lcServer   = Alltrim(.txtServer.Value)

        m.lcDatabase = Alltrim(.txtDatabase.Value)

        m.lcUserName = Alltrim(.txtUserName.Value)

        m.lcPassword = Alltrim(.txtPassword.Value)

 

        && Connection bilgisi.

        lcStringConn="Driver={MySQL ODBC 3.51 Driver};Port=3306"+;

                     ";Server=" + lcServer +;

                     ";Database=" + lcDatabase +;

                     ";Uid=" + lcUserName +;

                     ";Pwd=" + lcPassWord

 

        SQLSetProp(0,"DispLogin",3)

        .tnHandle = SQLStringConnect(lcStringConn)

        MessageBox(IIF(.tnHandle < 0, 'Baglanti saglanamadi', 'Baglandi' ), ;

            64,'Baglanti durumu',1000)

        .Caption = .Caption + ' - Baglanti Aktif'

        SwitchBtn(.t.)

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLDisconnect

******************************************************************

    With oForm

        If .tnHandle > 0

            SQLDisconnect(.tnHandle)

            MessageBox('Baglanti kesildi',64,'Baglanti durumu',1000)

            .Caption = 'MySQL Sample'

        EndIf 

        SwitchBtn(.f.)

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLList

******************************************************************

    With oForm

        If .tnHandle > 0

            && Listeleme icin ornek : 

            && mySQLExec(tnHandle, "select * from MySQLDB.MySQLTable", lcVFPTableName)

            mySQLExec(.tnHandle, ;

                "select ad,soyad,yas,maas from " + Alltrim(.txtDatabase.Value) + ;

                "." + Alltrim(.tcTable), 'liste')

            .grdListe.RecordSource = 'liste'

        EndIf 

        With .grdListe

            .Column1.Width = 150        

            .Column2.Width = 150        

            .Column3.Width = 75

            .Column4.Width = 100        

        EndWith 

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLNew

******************************************************************

    With oForm

        .txtAd.Enabled = .t.

        .txtAd.Value = ''

        .txtSoyad.Enabled = .t.

        .txtSoyad.Value = ''

        .txtYas.Enabled = .t.

        .txtYas.Value = ''

        .txtMaas.Enabled = .t.

        .txtMaas.Value = 0

        .cmdNew.Visible = .f.

        .cmdSave.Visible = .t.

        .grdListe.Enabled = .f.

        .txtAd.SetFocus()

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLSave

******************************************************************

    With oForm

        If .tnHandle > 0

            && Kayit icin ornek :

            && mySQLExec(tnHandle, 

            &&  "insert into MySQLDB.MySQLTable ('ad','soyad') Values ('Ali','Yuzer')", 

            &&  lcVFPTableName) 

            mySQLExec(.tnHandle, ;

                "insert into " + Alltrim(.txtDatabase.Value) + "." + Alltrim(.tcTable) +;

                " (`ad`,`soyad`,`yas`,`maas`) Values ('" + Alltrim(.txtAd.Value) + "','" + ;

                Alltrim(.txtSoyad.Value) + "','" + Alltrim(.txtYas.Value) + "','" +;

                Transform(.txtMaas.Value) + "')", +;

                'crsDummy')

 

            MessageBox('Kayıt işlemi'+Chr(13)+'başarıyla tamamlandı', 64, 'MySQL Sample', 2000)

        EndIf 

 

        .txtAd.Enabled = .f.

        .txtSoyad.Enabled = .f.

        .txtYas.Enabled = .f.

        .txtMaas.Enabled = .f.

        .cmdNew.Visible = .t.

        .cmdSave.Visible = .f.

        .cmdListe.Click()

        .grdListe.Enabled = .t.

        .grdListe.SetFocus()

 

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLEdit

******************************************************************

    With oForm

        && Bur örnekte sadece Yas veya Maas bilgisinin güncellenebilecegi 

        && kabul edilmistir. Siz istediginiz degisiklikleri gerektigi gibi

        && yapabilirsiniz.

        .txtYas.Enabled = .t.

        .txtMaas.Enabled = .t.

        .cmdEdit.Visible = .f.

        .cmdUpdate.Visible = .t.

        .grdListe.Enabled = .f.

        .txtYas.SetFocus()

    EndWith     

EndProc 

 

******************************************************************

Procedure mySQLUpdate

******************************************************************

    With oForm

        If .tnHandle > 0

            && Guncelleme icin ornek :

            && mySQLExec(tnHandle, 

            &&  "Update MySQLDB.MySQLTable SET maas='150' Where maas='100'", 

            &&  lcVFPTableName) 

            mySQLExec(.tnHandle, ;

                "Update " + Alltrim(.txtDatabase.Value) + "." + Alltrim(.tcTable) +;

                " SET yas='" + Alltrim(.txtYas.Value) + "', maas='" + ;

                Transform(.txtMaas.Value) + "' where ad = '" +;

                Alltrim(.txtAd.Value) + "' and  soyad = '" + Alltrim(.txtSoyad.Value) +;

                "'", "crsUpdate")

 

            MessageBox('Güncelleme işlemi'+Chr(13)+'başarıyla tamamlandı', 64, 'MySQL Sample', 2000)

        EndIf 

 

        .txtYas.Enabled = .f.

        .txtMaas.Enabled = .f.

        .cmdEdit.Visible = .t.

        .cmdUpdate.Visible = .f.

        .cmdListe.Click()

        .grdListe.Enabled = .t.

        .grdListe.SetFocus()

 

    EndWith 

EndProc 

 

******************************************************************

Procedure mySQLDelete

******************************************************************

    With oForm

        If .tnHandle > 0

            m.lnResult = MessageBox('Silmek istediğinize'+Chr(13)+'eminmisiniz?', ;

                4+32+256, 'MySQL Sample')

            If lnResult = 6

                && Silme icin ornek :

                && mySQLExec(tnHandle, 

                &&  "Delete From MySQLDB.MySQLTable Where Ad='Ali'", 

                &&  lcVFPTableName) 

                mySQLExec(.tnHandle, ;

                    "Delete From " + Alltrim(.txtDatabase.Value) + "." + Alltrim(.tcTable) +;

                    " Where ad='" + Alltrim(.txtAd.Value) + "' and soyad='" +;

                    Alltrim(.txtSoyad.Value) + "'", "crsDelete")

                

                MessageBox('Silme işlemi'+Chr(13)+'başarıyla tamamlandı', 64, 'MySQL Sample', 2000)

                .cmdListe.Click()

                .grdListe.SetFocus()

            EndIf 

        EndIf 

    EndWith 

EndProc 

 

******************************************************************

Function mySQLExec

    Lparameters tnHandle, tcSQL, tcCursorName

******************************************************************

    tcCursorName = iif(empty(tcCursorName),'',tcCursorName)

    If SQLExec(tnHandle,tcSQL,tcCursorName) < 0

        Do errHand with tcSQL

    EndIf

EndFunc 

 

******************************************************************

Function errHand

    Lparameters tcSQL

******************************************************************

    lcError=tcSQL+chr(13)

    Aerror(arrCheck)

    For ix=1 to 7

        lcError = lcError+trans( arrCheck [ix])+ chr(13)

    Endfor

    Messagebox(lcError,0,'Error def.')

EndFunc 

 

******************************************************************

Procedure SwitchBtn

    Lparameters tlState

******************************************************************

    With oForm

        .cmdDisconnect.Visible = tlState

        .cmdConnect.Visible = !tlState

        .cmdListe.Enabled = tlState

        .cmdNew.Enabled = tlState

        .cmdEdit.Enabled = tlState

        .cmdDelete.Enabled = tlState

    EndWith 

EndProc

Tekin Başöz
Yapay Zeka Ltd.

**yeliz__10** · 21.08.2008 09:09:15

yeliz__10
Üye
Offline

Yer: kocaeli
Kayıt Tarihi: 12.08.2008
İleti: 2

Re: VFP icinden MySQL kullanma

merhaba..doğru yere mi yazıyorum bilmiyorum ama amacım probelmime en kısa sürede çözüm bulmak...foxproya yeni giriş yaptım ve şuanki çalışmamda olmasını istediğim bir olayı gerçekleştiremiyorum.Olay şu ki: sgl de var olan bir tablomun içerisindeki bazı kısımları alıp yeni oluşturduğum başka bir tabloya bağlamak...mesela; "kitap" tablosu var ve bunun içinden "kitap adı" kısmını alıp yeni "teslimat" tablosundaki "kitap adı"alanında göstermek...

yardımcı olucağınaza inanarak teşekkür ederim...

**cetinbasoz** · 21.08.2008 10:58:36

cetinbasoz
Moderatör
Offline

Kayıt Tarihi: 07.10.2006
İleti: 2,314

Re: VFP icinden MySQL kullanma

Hosgeldin.

MySQL ile ilgili bir yere yazmissin, SQL server galiba ama farketmez sanirim. Sorun tam olarak anlasilmiyor. "tabloya baglamak"tan ne kastettigini anlamadim ozellikle. Verdigin ornege bakarak sankin soyle birsey istiyorsun:

SQL server:

SQL

1	SELECT kitap.kitapAdi INTO teslimat FROM kitap

VFP:

Visual Fox Pro

1	select kitap.kitapadi from kitap into table teslimat

Not: Dikkat et VFP ve SQL server arasndaki komut ayni degil.

"Teslimat" zaten var ise (hem SQL server hem VFP):

Visual Fox Pro

1	insert into teslimat (kitapAdi) select kitapAdi from kitap

Son düzenleyen, cetinbasoz (21.08.2008 11:01:12)

Yen yaz 1907'ye yolla FB gelsin evinde yensin.
(sonra salaklar ciksin alin terine şike desin)

**yeliz__10** · 21.08.2008 11:04:27

yeliz__10
Üye
Offline

Yer: kocaeli
Kayıt Tarihi: 12.08.2008
İleti: 2

Re: VFP icinden MySQL kullanma

hımm...evet tam anlatamamısım kendimi ama ben sizin söylediklerinizden yolu buldum..teşekkür ederim..

**river** · 21.08.2008 21:43:33

river
Üye
Offline

Kayıt Tarihi: 22.11.2006
İleti: 98

Re: VFP icinden MySQL kullanma

SQLEXEC ile INSERT kullanırken en buyuk sorun benim açımdan alan adlarını ve tabloya yazılması gereken değerleri tek tek ve doğru sırada parametre olarak geçirmek. Bu işi otomatik pilota bağlamak için bir örnek kod da ben göndereyim istedim.

Visual Fox Pro

#Define SQLCONNECTION   "DRIVER=SQL Server;"+;

                        "SERVER=.\SQLExpress;"+;

                        "DATABASE=TestData;"+;

                        "UID=sa;"+;

                        "PWD=sifreniz;"+;

                        "APP=Microsoft Visual FoxPro;"+;

                        "WSID=ENG-E4500"

 

 

sqch = SQLSTRINGCONNECT(SQLCONNECTION,.T.)

IF Sqch < 1

    ? "No Connection avaliable"

    CANCEL

ENDIF

 

SQLEXEC(sqch,"SELECT * From UserInfo","TmpCursor")

SELECT TmpCursor

*! DIKKAT uRec SCATTER NAME ile alındığı icin alan adları ile

*! objedeki alanlar bıre bır ortustu. Objeyı kendınız eklemek ıstedığınızde

*! INSERT deyiımının hata vermemesı ıcın tablodan gelecek olan alan adları kadar

*! property eklemeyı unutmayın.

SCATTER NAME urec

urec.USERID = 8

urec.USERNAME = "Murat"

urec.USEREMAIL = "[email protected]"

urec.UserTel = "0312 335 3"

 

*********************************************************

* ALAN SAYISININ 3-5 tane değil de çok fazla olduğunu varsayalım.

*/ValStr = "Values("+ALLTRIM(STR(uRec.UserID))+",'"+;

                               uRec.UserName+"','"+;

                               uRec.UserEMail+"','"+;

                               uRec.UserTel+"')"

 

*/FldStr = "(UserID,UserName,UserEMail,UserTel) "

*/? sqlexec(sqch,"INSERT INTO UserInfo "+FldStr+ValStr)

* ŞEKLİNDE UYGULAMAK YERİNE

***********************************************************

? SqlExec(sqch,"INSERT INTO UserInfo "+GetFieldNames(ALIAS())+GetFieldValues(ALIAS(),urec))

? SQLDISCONNECT(sqch)

 

 

FUNCTION GetFieldNames

 

PARAMETERS TableName

SELECT (TableName)

 

RetStr = "("

FOR k = 1 TO 255

    IF EMPTY(FIELD(k))

        EXIT

    EndIF

    RetStr = RetStr + IIF(k=1,"",",") + FIELD(k)

NEXT

 

RetStr = RetStr + ") "

 

RETURN RetStr

 

 

 

FUNCTION GetFieldValues

 

PARAMETERS TableName,objName

SELECT (TableName)

 

RetStr = "Values("

FOR k = 1 TO 255

    IF EMPTY(FIELD(k))

        EXIT

    ENDIF

    fldname = FIELD(k)

    fldval  = &fldName

    fldType = TYPE(fldName)

    fldval  = objname.&fldname

    fldstrval = ""

    DO Case

    CASE fldType = "N"

        fldstrval = ALLTRIM(STR(FldVal))

    CASE fldtype = "C"

        fldstrval = ALLTRIM(fldVal)

    ENDCASE

    IF !EMPTY(fldstrval)

        RetStr=RetStr+IIF(k=1,"",",")+IIF(fldtype="N","","'")+fldstrval++IIF(fldtype="N","","'")

    ENDIF

NEXT

 

RetStr = RetStr + ") "

 

RETURN RetStr

Son düzenleyen, river (21.08.2008 21:45:34)

**taRKan** · 22.08.2008 16:08:47

taRKan
Moderatör
Offline

Yer: Ankara
Kayıt Tarihi: 12.10.2006
İleti: 364

Re: VFP icinden MySQL kullanma

Murat,
Zannedersem senin yazdığın kodda karakter bir değer içeren alana içinde (') tek tırnak içeren bir değer yazmak istediğinde hata verir. Örneğin senin örnek için urec.USERNAME = "Murat'ın Adı" yazdığımızda

/o---------------------o\
www.haser.com
\o---------------------o/

**river** · 22.08.2008 20:04:21

river
Üye
Offline

Kayıt Tarihi: 22.11.2006
İleti: 98

Re: VFP icinden MySQL kullanma

Vardır elbet bir yolu Tarkan hocam.

Not : Ben bu tür örnek kodları zaten bizler için yazmıyorum. Görüyorum ki ilgili ve yeni başlayan arkadaşlar var, onlara sadece ( karınca kararınca ) - denebilirse eğer - bir tür paradigma değişimi için malzeme sunmaya çalışıyorum.

Hatta ona bakarsan Date type alanlar için de çalışmaz gibi duruyor bu kod. Bunu gözeterek düzenlenebilir tabi...

Son düzenleyen, river (22.08.2008 20:21:35)

**river** · 23.08.2008 09:05:34

river
Üye
Offline

Kayıt Tarihi: 22.11.2006
İleti: 98

Re: VFP icinden MySQL kullanma

Tarkan

senin sözünü ettiğin problemin çözümü açısından denemeler yaparken ilginç bir şey farkettim. Bilemiyorum bug mıdır değilmidir bile dedirtiyor bana...

sqlexec(sqch,"INSERT INTO UserInfo (UserID,UserName) Values(30,'Ahmet'"+"'in ismi')")

Bu kod tabloya "Ahmet'in ismi" olarak yazılıyor.

Benim asıl iletmek istediğim yaklaşım ise şöyle olacaktı

namevar = "Ahmet'in ismi"
sqlexec(sqch,"INSERT INTO UserInfo (UserID,UserName) Values(29,?nameVar)")

Son düzenleyen, river (23.08.2008 09:07:25)

**river** · 23.08.2008 09:26:42

river
Üye
Offline

Kayıt Tarihi: 22.11.2006
İleti: 98

Re: VFP icinden MySQL kullanma

Tarkan hocam bu da ilk örneğin yukarıda verilmeye çalışılan konsept çerçevesinde uyarlanmış hali

Visual Fox Pro

#Define SQLCONNECTION   "DRIVER=SQL Server;"+;

            "SERVER=.\SQLExpress;DATABASE=TestData;"+;

            "UID=sa;PWD=sifreniz;APP=Microsoft Visual FoxPro;"+;

            "WSID=ENG-E4500"

sqch = SQLSTRINGCONNECT(SQLCONNECTION,.T.)

IF Sqch < 1

  ? "No Connection avaliable"

  CANCEL

ENDIF

SQLEXEC(sqch,"SELECT * From UserInfo","TmpCursor")

SELECT TmpCursor

SCATTER NAME urec

urec.USERID = 16

urec.USERNAME = "Murat'in ismi"

urec.USEREMAIL = "[email protected]"

urec.UserTel = "0312 335 3"

 

*********************************************************

* ALAN SAYISININ 3-5 tane degil de çok fazla oldugunu varsayalim.

*/ValStr = "Values("+ALLTRIM(STR(uRec.UserID))+",'"+;

                 uRec.UserName+"','"+;

                 uRec.UserEMail+"','"+;

                 uRec.UserTel+"')"

 

*/FldStr = "(UserID,UserName,UserEMail,UserTel) "

*/? sqlexec(sqch,"INSERT INTO UserInfo "+FldStr+ValStr)

* SEKLINDE UYGULAMAK YERINE

***********************************************************

ValStr = GetFieldValues(ALIAS(),urec)

*/? SqlExec(sqch,"INSERT INTO UserInfo "+GetFieldNames(ALIAS())+GetFieldValues(ALIAS(),urec))

? SqlExec(sqch,"INSERT INTO UserInfo "+GetFieldNames(ALIAS())+GetFieldParams(ALIAS(),urec))

? SQLDISCONNECT(sqch)

 

 

FUNCTION GetFieldNames

 

PARAMETERS TableName

SELECT (TableName)

 

RetStr = "("

FOR k = 1 TO 255

  IF EMPTY(FIELD(k))

    EXIT

  EndIF

  RetStr = RetStr + IIF(k=1,"",",") + FIELD(k)

NEXT

 

RetStr = RetStr + ") "

 

RETURN RetStr

 

 

 

FUNCTION GetFieldValues

 

PARAMETERS TableName,objName

SELECT (TableName)

 

RetStr = "Values("

FOR k = 1 TO 255

  IF EMPTY(FIELD(k))

    EXIT

  ENDIF

  fldname = FIELD(k)

  fldType = TYPE(fldName)

  fldval  = objname.&fldname

  fldstrval = ""

  DO Case

  CASE fldType = "N"

    fldstrval = ALLTRIM(STR(FldVal))

  CASE fldtype = "C"

    fldstrval = ALLTRIM(fldVal)

  ENDCASE

  IF !EMPTY(fldstrval)

    RetStr=RetStr+IIF(k=1,"",",")+IIF(fldtype="N","","'")+fldstrval++IIF(fldtype="N","","'")

  ENDIF

NEXT

 

RetStr = RetStr + ") "

 

RETURN RetStr

 

 

 

 

FUNCTION GetFieldParams

 

PARAMETERS TableName,objName

SELECT (TableName)

 

RetStr = "Values("

FOR k = 1 TO 255

  IF EMPTY(FIELD(k))

    EXIT

  ENDIF

  RetStr=RetStr+IIF(k=1,"",",")+"?urec."+FIELD(k)

NEXT

 

RetStr = RetStr + ") "

 

RETURN RetStr

urec.USERNAME = "Murat'in ismi" olduğuna dikkat etmenizi rica ederim.

Son düzenleyen, river (23.08.2008 09:29:43)

**cetinbasoz** · 23.08.2008 15:55:56

cetinbasoz
Moderatör
Offline

Kayıt Tarihi: 07.10.2006
İleti: 2,314

Re: VFP icinden MySQL kullanma

river yazdı:

Tarkan
senin sözünü ettiğin problemin çözümü açısından denemeler yaparken ilginç bir şey farkettim. Bilemiyorum bug mıdır değilmidir bile dedirtiyor bana...
sqlexec(sqch,"INSERT INTO UserInfo (UserID,UserName) Values(30,'Ahmet'"+"'in ismi')")
Bu kod tabloya "Ahmet'in ismi" olarak yazılıyor.
Benim asıl iletmek istediğim yaklaşım ise şöyle olacaktı
namevar = "Ahmet'in ismi"
sqlexec(sqch,"INSERT INTO UserInfo (UserID,UserName) Values(29,?nameVar)")

Bug degil doğrusu o. SQL serverda ' kullanmak istiyorsan iki tane ' yani '' kullanman gerekiyor.

Murat,
En son orneğindeki gibi parametre kullanırsan (?uRec.fieldname):
-Karakter alanlarındaki özel karakterleri halledersin
-Datatipleri arasındaki cevirimleri VFP senin adına yapar
EN ÖNEMLİSİ
-SQL Injection Attack denen saldırılardan korunursun.

Yen yaz 1907'ye yolla FB gelsin evinde yensin.
(sonra salaklar ciksin alin terine şike desin)

**river** · 23.08.2008 19:16:00

river
Üye
Offline

Kayıt Tarihi: 22.11.2006
İleti: 98

Re: VFP icinden MySQL kullanma

Çetin hocam iyi de ben orada iki tane yani >''< göremiyorum ki sonuçta stringleri toplayıp baktığımda.... ( Ya da ben atlıyorum. ) Amacım zaten iki tane ' yapmaktı ki birini alsın. Hatta bir de C# de biliyorsun \ hikayesi de var falan filan ama ben burada "'Ahmet'"+"'in ismi'" ların toplamını SQL e gönderdiğimde elde var 'Ahmet in ismi' ya ben iyi bakamıyorum ya da hakkaten burda bir gariplik var abi.

Üstadım bu SQL injection attacklar hakkında diyeceklerin varsa ve okursak hayır duası alırsın benden. Okumak isterim ama vaktin olurmu bilmem.

Özel Not : UMARIM HERŞEY İYİDİR. RAHATSIZ ETMEMEK İÇİN ARAMADIM.

Son düzenleyen, river (23.08.2008 19:19:02)

**taRKan** · 25.08.2008 10:29:43

taRKan
Moderatör
Offline

Yer: Ankara
Kayıt Tarihi: 12.10.2006
İleti: 364

Re: VFP icinden MySQL kullanma

Merhaba River,
Geç cevap yazdım kusura bakmayın.
SQL işin içine girdiği zaman ben hep SPT (SQL Pass Through) kullanmayı tercih etmişimdir.
Ne cursorapadtor ne de remoteview SPT ile yapamadığım hiç bir şey yok.
SQLExec komutunu kullanırkende parametrik yani senin en son yazdığın gibi ? değişkenleri kullanırım. Çetin'in de dediği gibi VFP gerekli veri tipleri değişimini kendisi yapıyor.

/o---------------------o\
www.haser.com
\o---------------------o/

**cetinbasoz** · 25.08.2008 19:16:06

cetinbasoz
Moderatör
Offline

Kayıt Tarihi: 07.10.2006
İleti: 2,314

Re: VFP icinden MySQL kullanma

(Murat, hersey yoluna girdi, sagol. Artik ise dondum)

Murat,
Dikkatli bak o string + string sonucunda Ahmet sonrasi iki tane ' koymus oluyorsun:) Asil onemli olan "SQL Injection Attack" ( SIA diyelim kisaca).

SIA oyle buyuk bir tehlikeki onunla guvenli oldugu dusunulen siteler gocertilip haberlere konu oldu defalarca. Hatta youtube'ta bile nasil SIA yapildigini gosteren filmler var:) VFPciler pek fazla bilmiyor gibi bu SIAyi cunku imlansiz olmasa da VFP datasinda yapmak cok zor. Ama isin icine SQL server, Oracle, mySQL ... vs bir backend giriyorsa benden tavsiye (eger 100% emin olamiyorsan iseriginden) + ... + seklinde parametreleri doldurulmus komut gonderme sakin.

Cok basit bir ornek problem icin, diyelimki soyle bir SQLin var

SQL

1	SELECT * FROM myTable WHERE userName = 'varName'

ve bunu:

Visual Fox Pro

1	lcSQL = "select * from myTable where userName = '" + varName +"'"

seklinde kullaniyorsun. varNAme parametre degil, dumduz kullanicidan ne gelyorsa o ekleniyor. Ve iste o noktada kullanici sunu giriyor:

Visual Fox Pro

1	x' or 'a' = 'a

ve komut:

SQL

1	SELECT * FROM myTable WHERE userName = 'x' OR 'a' = 'a'

Halini aliyor:) Neyseki bu insafli bir saldiri gene de.

Yen yaz 1907'ye yolla FB gelsin evinde yensin.
(sonra salaklar ciksin alin terine şike desin)

**cetinbasoz** · 25.08.2008 19:20:25

cetinbasoz
Moderatör
Offline

Kayıt Tarihi: 07.10.2006
İleti: 2,314

Re: VFP icinden MySQL kullanma

Tarkan,
SPT'nin problemleri yeni basliyor bence. Su anda varligini gostermek zor ama temelde problem VFP yeni SQL tiplerini tanimiyor. XML data ornegin. Eger SQL native client driver ile alirsan eline gecen 0 uzunlugunda string. Eski driver simdilik idare ediyor ama nereye kadar eski driver ile calisilacak. O nedenle ben simdiden ADO ve CursorAdapter'a gectim.

Yen yaz 1907'ye yolla FB gelsin evinde yensin.
(sonra salaklar ciksin alin terine şike desin)

**taRKan** · 27.08.2008 20:56:23

taRKan
Moderatör
Offline

Yer: Ankara
Kayıt Tarihi: 12.10.2006
İleti: 364

Re: VFP icinden MySQL kullanma

Çetin,
Bilgi için teşekkür ederim.
SQL'in yeni tiplerini hiç kullanmıyorum o yüzden sorun olmuyor
Ancak hiç istemesemde VFP'dan yavaş yavaş .Net'e geçiyoruz.

/o---------------------o\
www.haser.com
\o---------------------o/

VFP icinden MySQL kullanma

İleti [ 20 ]

1 Konuyu açan tbasoz 13.10.2006 13:47:28

Konu: VFP icinden MySQL kullanma

2 Cevaplayan soykanozcelik 13.10.2006 14:50:23

Re: VFP icinden MySQL kullanma

3 Cevaplayan mrduyar 13.10.2006 16:37:40

Re: VFP icinden MySQL kullanma

4 Cevaplayan ahmetozkaya 15.10.2006 01:31:26

Re: VFP icinden MySQL kullanma

5 Cevaplayan Ozgur 16.10.2006 14:28:58

Re: VFP icinden MySQL kullanma

6 Cevaplayan tbasoz 21.04.2007 09:06:39

Re: VFP icinden MySQL kullanma

7 Cevaplayan yeliz__10 21.08.2008 09:09:15

Re: VFP icinden MySQL kullanma

8 Cevaplayan cetinbasoz 21.08.2008 10:58:36

Re: VFP icinden MySQL kullanma

9 Cevaplayan yeliz__10 21.08.2008 11:04:27

Re: VFP icinden MySQL kullanma

10 Cevaplayan river 21.08.2008 21:43:33

Re: VFP icinden MySQL kullanma

11 Cevaplayan taRKan 22.08.2008 16:08:47

Re: VFP icinden MySQL kullanma

12 Cevaplayan river 22.08.2008 20:04:21

Re: VFP icinden MySQL kullanma

13 Cevaplayan river 23.08.2008 09:05:34

Re: VFP icinden MySQL kullanma

14 Cevaplayan river 23.08.2008 09:26:42

Re: VFP icinden MySQL kullanma

15 Cevaplayan cetinbasoz 23.08.2008 15:55:56

Re: VFP icinden MySQL kullanma

16 Cevaplayan river 23.08.2008 19:16:00

Re: VFP icinden MySQL kullanma

17 Cevaplayan taRKan 25.08.2008 10:29:43

Re: VFP icinden MySQL kullanma

18 Cevaplayan cetinbasoz 25.08.2008 19:16:06

Re: VFP icinden MySQL kullanma

19 Cevaplayan cetinbasoz 25.08.2008 19:20:25

Re: VFP icinden MySQL kullanma

20 Cevaplayan taRKan 27.08.2008 20:56:23

Re: VFP icinden MySQL kullanma

İleti [ 20 ]